Two syntax forms are available for the Perl chr function:

chr EXPR 
chr

• has as argument a number or an expression which after evaluation will return a number
• returns the character represented by the EXPR

#!/usr/local/bin/perl

use strict;
use warnings;

print chr(65), "\n";
# it displays: A

print chr(0x41), "\n";
# it displays: A

my $str = chr(0x263a);
print length $str, "\n";
# it displays: 1 (character context)

{
  use bytes;
  print length $str, "\n";
  # it displays: 3 (bytes pragma context)
}

my $str = chr(0x263a);

Instead of using the Perl chr function to initialize a string with Unicode characters, you can use hexadecimal escapes. A hexadecimal escape begins with \x and it is either followed by a two digit hexadecimal number (for example "\x30" is "0") or a hexadecimal of arbitrary length included in curly braces (\x{263a}).

So, you could write:

my $str = "\x{263a}";

my $str = chr(0x263a);

#!/usr/local/bin/perl

use strict;
use warnings;

# initialize a string 
my $str = "72 101 108 108 111 32 87 111 114 108 100 33";

# split the string into an array of characters
my @array = split / /,$str;

# converts the elements of the array into characters
@array = map (chr, @array);

# join the elements of the array into the $str
$str = join "",@array;

# finnaly, print the string
print "$str\n";
# it outputs: Hello World!

• the $str scalar variable is initialized with a sequence of ASCII codes, separated by space
• the split function is used with the space pattern (" ") delimiter and it will return an array with the ASCII codes
• the map function will run the Perl chr function for each element of the @array; at each iteration step the current element is assigned in turn to $_ and next the chr function will act against the special variable $_; the map function returns the same array but having characters as elements
• the @array elements will be concatenated into $str by using the join function without any delimiter ("")

@array = map (chr, @array);

@array = map (chr $_, @array);
@array = map { chr } @array;
@array = map { chr $_ } @array;

A quicker alternative to do this is by using the pack function, as in the following example:

#!/usr/local/bin/perl

use strict;
use warnings;

my $str = "72 101 108 108 111 32 87 111 114 108 100 33";

# split the string into an array of characters
my @array = split / /,$str;
$str = pack("C*", @array);
print "$str\n";
# it displays: Hello World!

#!/usr/local/bin/perl

use strict;
use warnings;

my $str = "48656c6c6f20576f726c6421";

$str =~ s/([a-fA-F0-9][a-fA-F0-9])/chr(hex($1))/eg;
print $str, "\n";
# it displays: Hello World!

• the $str scalar variable is initialized with a few 2-digit hexadecimal values
• in order to convert the hex string stored in $str to a character string the s/// substitution operator is used:
• ([a-fA-F0-9][a-fA-F0-9]) match any two hexadecimal digits and store them in $1 - the using of round parentheses allow us to store the matched expression in the special variable named $1 and if you have more parentheses, the expression included in the second parenthesis will be assigned to $2, and so on
• chr(hex($1) represents the replacement argument of the substitution operator; the hex function will convert the hexadecimal string stored in $1 in its decimal corresponding value and it will return this value; the chr function will return the character represented by the numeric value returned by the hex function
• e is a modifier and it tells the regex engine to treat the replacement field as Perl code
• g is a modifier and tells the regex engine to repeatedly apply the substitution for all the characters of the string, starting with the first one

Hello World!