The syntax forms are:

keys %hash
keys @array

• a list with the hash keys – in a list context (this list can be used for further processing)
• the number of the hash elements (key-value pairs) – in scalar context

#!/usr/local/bin/perl

use strict;
use warnings;

# initialize a hash with a few elements
my %hash = (father => 'John', mother => 'Alice', 
            son => 'Andrew', daughter => 'Mary');
            
# print the hash by using foreach and keys
print "The keys are: ";
foreach my $key (keys % hash) {
  print "$key ";
}
print "\n";

The keys are: son daughter father mother

The counterpart of the keys function is the values function which in a list context returns the values of the hash. Even though the order of returning the elements is random, you can count on the same order if you call any of the each, keys or values function on the same hash.

Each hash and array used in your script has a unique internal iterator and calling the Perl keys function has as effect the resetting of this iterator.

Next, I’ll show you an example where the keys function is used in a scalar context:

#!/usr/local/bin/perl

use strict;
use warnings;

my %hash = ();
my $count = 1;

while (keys %hash < 10) {
  $hash{++$count} = $count * 2 - 1;  
} 

foreach my $key ( sort {$a <=> $b} keys %hash){
  print "$hash{$key} "
}
print "\n";

If you run this code you’ll get as output:

1 3 5 7 9 11 13 15 17 19

As you can see, you’ll get as output the first ten odd numbers. What is interesting here is the while loop. The keys function is invoked here in a scalar context and it will return the number of the hash keys.

Inside the while loop we’ll add a (key, value) pair element to our %hash, until the hash has 10 elements, when the loop will end. The hash values are the first ten odd numbers.

To print the hash values a foreach loop is used. The hash values will be printed in an ascending numerical order of the keys using the sort and print functions.

to see a lot of fully commented examples that help you use the Perl built-in functions in your scripts.

#!/usr/local/bin/perl

use strict;
use warnings;

my @array = (1, 2, 3, 4);
$#array = 9;

print("The indices are: ", join(' ', keys @array), "\n");

This snippet will produce the following result:

The indices are: 0 1 2 3 4 5 6 7 8 9

Finally, you can get the array size (the number of elements of an array) by using the Perl keys function in a scalar context, as you can see in the following code line:

my $size = keys @array;