In this short tutorial we’ll show you some samples about how to use it for manipulating strings, either you use it alone or in context with other string functions like index or length.

A lot of strings manipulation can be done using the power of regular expressions but in many cases, the built-in string functions are straightforward and take less time to execute.

To begin with, let’s see the syntax forms available for Perl substr function:

substr EXPR, OFFSET, LENGTH, REPLACEMENT
substr EXPR, OFFSET, LENGTH
substr EXPR, OFFSET

• EXPR is a string expression from which the substring will be extracted
• OFFSET is an index from where the substring to be extracted starts
• LENGTH is the length of the substring to extract
• REPLACEMENT is a string that will replace the substring

Like in the case with other functions, you can use the parentheses or not, do it as you wish. As you can see above, some arguments are mandatory and others are optional. You must mention at least the string expression (EXPR) and the position (OFFSET) from where the substring to be extracted starts.

Before reviewing the Perl substr function parameters, I want to remind you that in Perl the first character of a string has the index 0, the second 1, and so on. Actually, you can modify this by setting the special variable $[ with whatever you want, but be careful however if you decide to change it. For strings $[ is the index of the first character of the string and by default is set to 0.

Take a moment to look at the following example and see a code sample about how to use the Perl substr function:

my $names = "John Peterson Anne Mike";
my $oneName = substr($names, 5, 8);
print "$names\n";
#it prints John Peterson Anne Mike
print "$oneName\n";  
#it prints Peterson

We can use Perl substr function either in various comparisons or like a lvalue such as an assignment. In this last case, if the EXPR will be a string variable, the value of the string variable will be modified. See the next block of code for this:

my $names = "Alin Fred John";
substr($names, 5, 4) = "Mary";
print "$names\n";
# it prints Alin Mary John

to see a lot of fully commented examples that help you use the Perl statements and the Perl buit-in functions in your scripts.

OFFSET could be:

• positive – the substring starts that far from the beginning of the string
• negative – the substring starts that far from the end of the string
• 0 - that means that the substring starts at the first character of the string

If the substring is used like a lvalue, and the OFFSET is entirely outside the expression string, a fatal error will be issued. See the following snippet code to illustrate the cases discussed above:

my $names = "Alin Fred Peter";
my $oneName = substr($names, -10, 4);
print "Name: $oneName\n";
$oneName = substr $names, -100, 4;
print "Name: $oneName\n";
substr($names, 20, 5) = "Alice";

Name: Fred
Name:
substr outside of string at 1.pl line 6.

LENGTH could be:

• omitted – the function will return all the characters beginning with the OFFSET position up to the end character of the string
• positive – the function will return from the string maximum LENGTH characters beginning with the OFFSET position
• negative – it will return the substring starting with the OFFSET position but without that many characters off the end of the string
• 0 – in this case the returned substring will be empty, no error warning

my $names = "Alex James Abby Shannon Monica";
my $strNames = substr $names, 11;  # length omitted
print "$strNames\n";
# prints Abby Shannon Monica
$strNames = substr $names, 24, 100; # length = 100
print "$strNames\n";           
# prints Monica
$strNames = substr $names, 24, -2;  # length = -2
print "$strNames\n";           
# prints Moni

my $names = "Alex James Abby Shannon Monica";
substr($names, 11, 4) = "Alexandra";
print "$names\n";           
# prints Alex James Alexandra Shannon Monica

Next, look at an example where the substring used to be assigned is shorter than the LENGTH supplied to Perl substr function:

my $names = "Alex James Abby Shannon Monica";
substr($names, 11, 4) = "Tom";
print "$names\n"; 
# prints Alex James Tom Shannon Monica

You can play around with these examples to see how the Perl substr function works in other similar situations.

REPLACEMENT

my $names = "Alex James Abby Shannon Monica";
substr $names, 16, 7, "Alexandra"; 
# it will replace "Shannon" with "Alexandra"
print "$names\n"; 
# it prints Alex James Abby Alexandra Monica

to see a lot of fully commented examples that help you use the Perl statements and the Perl buit-in functions in your scripts.

For instance, let’s suppose that each record of the file customers.txt includes the fields Name, Phone and ZipCode and the entire file has only three records, like in the next figure:

Fixed-width columns

We’ll examine first the case when the fields have fixed width: Name – 20, Phone – 12 and ZipCode – 5. If we’ll print the file, we’ll get something like this:

John Abbot          872-321-121255416
Clark Eliot         205-321-120020037
Johnny Randolph     345-767-347633702

open FILE, "customers.txt" or die $!;
while (<FILE>) 
{
  # chomp off the possible ending newline from $_
  chomp;
  my $name = substr($_,0, 20);
  #Trim the end trailling spaces 
  $name =~ s/ +$//;
  my $phone = substr($_,20, 12);
  # delete all '-' characters
  $phone =~ s/-//g;
  my $zipCode = substr($_, 20+12, 5);
  print $name, ",",$phone, ",",$zipCode, "\n";
}
close FILE;

John Abbot,8723211212,55416
Clark Eliot,2053211200,20037
Johnny Randolph,34576734763,33702

The next example will illustrate the case when the fields are delimited by a separator character like comma. In this case the content of our file will be:

John Abbot,872-321-1212,55416
Clark Eliot,205-321-1200,20037
Johnny Randolph,345-767-34763,33702

open FILE, "customers.txt" or die $!;
while (<FILE>) 
{
  # chomp off the possible ending newline
  chomp;
  my $pos1 = index($_, ","); 
  my $name = substr($_,0, $pos1);
  my $pos2 = index $_, ",", $pos1+1; 
  my $phone = substr($_,$pos1+1, $pos2-$pos1-1);
  # delete all - characters
  $phone =~ s/-//g;
  my $zipCode = substr($_, $pos2+1, length($_)-$pos2);
  print $name,",",$phone,",",$zipCode,"\n";
}
close FILE;

Please click here to download the Perl substr script with all the above examples included.

to see a lot of fully commented examples that help you use the Perl statements and the Perl buit-in functions in your scripts.